# Maintainer: s1d3sw1ped <https://git.s1d3sw1ped.com/s1d3sw1ped>
# Unofficial Arch/CachyOS repackage of the official Grok Bot .deb.
# Temporary until upstream ships a native package.
#
# Version oracle (commit is in the download URL):
#   https://api2.cursor.sh/updates/api/update/linux-x64/sand/0.0.0/00000000-0000-0000-0000-000000000000/stable
# Deb URL:
#   https://downloads.cursor.com/grokbot/stable/<commit>/linux/x64/grok-bot_<pkgver>_amd64.deb

pkgname=grok-bot-bin
pkgver=0.35.0
_commit=1c5a6ceb364c4dd53f0069f72cc4239220ed471e
pkgrel=2
pkgdesc="Grok Bot desktop agent (official .deb repackaged)"
arch=('x86_64')
url="https://cursor.com/download/bot"
license=('LicenseRef-proprietary')
depends=(
  'alsa-lib'
  'at-spi2-core'
  'gtk3'
  'libdrm'
  'libnotify'
  'libsecret'
  'libxkbcommon'
  'libxss'
  'libxtst'
  'mesa'
  'nss'
  'xdg-utils'
)
optdepends=(
  'libappindicator-gtk3: tray icon support'
  'curl: auto-update check on launch'
)
provides=('grok-bot' 'sand')
conflicts=('grok-bot' 'sand')
replaces=('sand')
options=('!strip' '!debug')
source=(
  "https://downloads.cursor.com/grokbot/stable/${_commit}/linux/x64/grok-bot_${pkgver}_amd64.deb"
  "grok-bot-launch.sh"
)
noextract=("grok-bot_${pkgver}_amd64.deb")
sha256sums=('ed254e819d0f0419a1df9771009363074f65f80d8175d2ee0fc62900087ebd99')
  'fb888b2204c8a51c71a9f5f9a2913ac10561f3ef6939c1245ecae4e837d4ada2'
  '886c8b55eb44d2f7812be50dcc1571907dc2d7e755171e67e916f497634f09eb'
)

package() {
  bsdtar -O -xf "$srcdir/grok-bot_${pkgver}_amd64.deb" data.tar.xz \
    | bsdtar -xJf - -C "$pkgdir"

  # Auto-update launch shim (not a plain symlink into /opt).
  install -Dm755 "$srcdir/grok-bot-launch.sh" "$pkgdir/usr/bin/grok-bot"
  # Keep provides(sand) on PATH; both names run the same shim.
  ln -sf grok-bot "$pkgdir/usr/bin/sand"

  # Path contains a space, so Chromium cannot use the SUID sandbox.
  # Arch/CachyOS kernels have user namespaces; keep chrome-sandbox non-setuid.
  if [[ -f "$pkgdir/opt/Grok Bot/chrome-sandbox" ]]; then
    chmod 0755 "$pkgdir/opt/Grok Bot/chrome-sandbox"
  fi

  install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
  ln -sf "/opt/Grok Bot/LICENSE.electron.txt" \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE.electron.txt"
  ln -sf "/opt/Grok Bot/LICENSES.chromium.html" \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSES.chromium.html"
}